Sort two arrays (volume, prices) taking the prices as the reference and ordering the pair volumes, price

Question

I am currently trying to sort two arrays that are paired in terms of index, however, I want to sort the first array and second array taking the first array as the reference for the indexes order. Please find below my code :

int tmpIndexMin = 0
float tmpMinClose = 0.0
    for i = 0 to array.size(closeArray) - 1
    tmpMinClose := array.min(closeArray)
    tmpIndexMin := array.indexof(closeArray, tmpMinClose)
    array.push(closeArraySorted, tmpMinClose)
    array.push(volumeArraySorted, array.get(volumeArray, tmpIndexMin))
    array.remove(closeArray, tmpIndexMin)
    array.remove(volumeArray, tmpIndexMin)

I get an error on the second loop (with initial arrays size at 9 instead of 10), the array.get fails and returns -1.

Any idea of what I am doing wrong here ? PS : All the values that are not initialized in this code are initialized before

I tried to initialize the tmp values outside of the loop (initially inside the loop) and I added the operator := to reassign but it's not working. Thanks by advance !

Answer 1

If I understand correctly, you are trying to sort both arrays but keep the indexes paired up. You can do this using the array.sort_indices function.

See below example. Two arrays, one of the last 5 closes and one of the last 5 volumes.

Top table displays the close with the matching volume based on the original array. The second table displays the same, however it is sorted in ascending order of the closing prices. Notice each close/volume pair stays the same.

/@version=5
indicator("My script", overlay = true)
priceArr = array.from(close, close[1], close[2], close[3], close[4])
volArr = array.from(volume, volume[1], volume[2], volume[3], volume[4])
sorted = array.sort_indices(priceArr)

var table data = table.new(position.top_right, 2,6)
if barstate.islast
    data.cell(0,0, 'Price', text_color = color.white)
    data.cell(1,0, 'Volume', text_color = color.white)
    for i = 0 to 4
        data.cell(0,i+1, str.tostring(priceArr.get(i)), text_color = color.white)
    for i = 0 to 4
        data.cell(1,i+1, str.tostring(volArr.get(i)), text_color = color.white)


var table data2 = table.new(position.middle_right, 2,6)
if barstate.islast
    data2.cell(0,0, 'Price', text_color = color.white)
    data2.cell(1,0, 'Volume', text_color = color.white)
    for i = 0 to 4
        data2.cell(0,i+1, str.tostring(priceArr.get(sorted.get(i))), text_color = color.white)
    for i = 0 to 4
        data2.cell(1,i+1, str.tostring(volArr.get(sorted.get(i))), text_color = color.white)