Stored procedure not returning results from table variable?

Question

I have a stored procedure that I'm working on and I'm trying to get it to return the results that are stored into a table variable that I created within the procedure. For some reason, its not returning anything when I execute the procedure. However, if I take the piece of code used to populate the table variable and take it out of the procedure it works...

The code is as follows:

Test Code

DECLARE @RC int
DECLARE @constraint_names nvarchar(max)
DECLARE @column_names nvarchar(max)
DECLARE @table_name nvarchar(max)
DECLARE @table_schema nvarchar(max)
DECLARE @database_name nvarchar(max)
DECLARE @debug int
DECLARE @ExistFlag int;

-- TODO: Set parameter values here.
SET @column_names = 'M2016_Object_ID int, Name varchar(50), a int, b'
SET @table_name = 'tblM2016_Objects';
SET @debug = 0;
SET @ExistFlag = 1;

DECLARE @existing_cols TABLE (Value nvarchar(max));
INSERT INTO @existing_cols EXEC spM2016_CheckColumnExistence_tblM2016 
@column_names, @table_name,  @database_name, @table_schema, 1, 0;
select * from @existing_cols

Results

Value
M2016_Object_ID int
Name varchar(50)

This is the expected result since I'm testing to see if M2016_Object_ID and Name column exist in the tblM2016_Objects table.

However, when I execute this inside the stored procedure I'm working on, it returns nothing.

Stored Procedure

ALTER PROCEDURE spM2016_ChangePKConstraints_tblM2016 
-- Add the parameters for the stored procedure here
    @constraint_names   nvarchar(max) = 
N'PK_tblM2016_Fields_M2016_Field_ID',
    @column_names       nvarchar(max) = N'M2016_Field_ID',
    @table_name         nvarchar(max) = N'tblM2016_Fields', 
    @table_schema       nvarchar(max) = N'dbo',
    @database_name      nvarchar(max) = N'MET',
    @debug              int = 0
AS
BEGIN
-- SET NOCOUNT ON added to prevent extra result sets from
-- interfering with SELECT statements.
SET NOCOUNT ON;

-- Insert statements for procedure here
DECLARE @tbl_name       nvarchar(max) = N'tblM2016_Fields',
        @col_names      nvarchar(max) = N'M2016_Field_ID',
        @tbl_schema     nvarchar(max) = N'dbo',
        @db_name        nvarchar(max) = N'MET',
        @tbl_full_name  nvarchar(max),
        @tbl_short_name nvarchar(max),
        @sql            nvarchar(max),
        @params         nvarchar(max)

-- Insert statements for procedure here

SET @col_names = ISNULL(NULLIF(@column_names, ''), @col_names);
SET @tbl_name = quotename(ISNULL(NULLIF(@table_name, ''), @tbl_name));
SET @tbl_schema = quotename(ISNULL(NULLIF(@table_schema, ''), @tbl_schema));
SET @db_name = quotename(ISNULL(NULLIF(@database_name, ''), @db_name));

SET @tbl_full_name =  @db_name + '.' + @tbl_schema + '.' + @tbl_name;
SET @tbl_short_name = @tbl_schema + '.' + @tbl_name;

DECLARE @existing_cols TABLE (Value nvarchar(max));
DECLARE @nonexisting_cols TABLE (Value nvarchar(max));

--INSERT INTO @split_columns
--  SELECT *
--  FROM 
--  fnM2016_Split_String_Inline(@col_names, ',');

--IF (@debug = 1)
--  SELECT * FROM @split_columns;

IF NOT EXISTS (SELECT * FROM sys.objects WHERE type = 'PK' AND parent_object_id = OBJECT_ID(@tbl_full_name))
BEGIN
    -- No PK constraint, check col_names to see which exist and don't exist
    INSERT INTO @existing_cols EXEC spM2016_CheckColumnExistence_tblM2016 @col_names, @tbl_name,  @db_name, @tbl_schema, 1, 0;

    INSERT INTO @nonexisting_cols EXEC spM2016_CheckColumnExistence_tblM2016 @col_names, @tbl_name,  @db_name, @tbl_schema, 0, 0;

    SELECT * FROM @existing_cols;

    SELECT * FROM @nonexisting_cols;

END
--ELSE
--BEGIN

--END

END

Results These are the results after executing the procedure with the same parameter values in the test above:

EXECUTE @RC = [dbo].[spM2016_ChangePKConstraints_tblM2016] 
 @constraint_names
,@column_names
,@table_name
,@table_schema
,@database_name
,@debug;

Result

Value

The table purposely does not have a primary key. Proof:

Answer 1

I figured out the issue. My @table_name, @table_schema, and @database_name being passed into the spM2016_CheckColumnExistence_tblM2016 procedure inside the spM2016_ChangePKConstraints_tblM2016 were already escaped through the call to quotename(). Inside the spM2016_CheckColumnExistence_tblM2016, I also do a qutoename() of the parameters as a validation check against bad table, database, and schema names. That procedure code was left out and I apologize for that.

Essentially the problem area is here (with problem parameters highlighted with **)

Problem code in spM2016_ChangePKConstraints_tblM2016

INSERT INTO @existing_cols EXEC spM2016_CheckColumnExistence_tblM2016 @col_names, **@tbl_name**,  **@db_name**, **@tbl_schema**, 1, 0;

Notice that those parameters being passed to spM2016_CheckColumnExistence_tblM2016 have already been escaped with quotename() above in the spM2016_ChangePKConstraints_tblM2016 procedure. Now, here is the missing key code in the spM2016_CheckColumnExistence_tblM2016 procedure:

Problem code in spM2016_CheckColumnExistence_tblM2016

ALTER PROCEDURE spM2016_CheckColumnExistence_tblM2016 
-- Add the parameters for the stored procedure here
@column_names   nvarchar(max) = N'M2016_Field_ID int', 
@table_name     nvarchar(max) = N'tblM2016_Fields',
@database_name  nvarchar(max) = N'MET',
@table_schema   nvarchar(max) = N'dbo',
@ExistFlag      int          = 1,                       -- Check for column existence in given table = 1
                                                        -- Check for column non-existence in given table = 0
@debug          int          = 0                    
AS
BEGIN
-- SET NOCOUNT ON added to prevent extra result sets from
-- interfering with SELECT statements.
SET NOCOUNT ON;

 -- Insert statements for procedure here
DECLARE @tbl_name       nvarchar(max) = N'tblM2016_Fields',
        @col_names      nvarchar(max) = N'M2016_Field_ID',
        @tbl_schema     nvarchar(max) = N'dbo',
        @db_name        nvarchar(max) = N'MET',
        @tbl_full_name  nvarchar(max),
        @tbl_short_name nvarchar(max)

-- Insert statements for procedure here

***** PROBLEM STARTS HERE *****
SET @col_names = ISNULL(NULLIF(@column_names, ''), @col_names);
SET @tbl_name = quotename(ISNULL(NULLIF(@table_name, ''), @tbl_name));
SET @tbl_schema = quotename(ISNULL(NULLIF(@table_schema, ''), @tbl_schema));
SET @db_name = quotename(ISNULL(NULLIF(@database_name, ''), @db_name));

SET @tbl_full_name =  @db_name + '.' + @tbl_schema + '.' + @tbl_name;
SET @tbl_short_name = @tbl_schema + '.' + @tbl_name;

I've highlighted the issue with ***** PROBLEM STARTS HERE ***** for clarity. As you can see, spM2016_CheckColumnExistence_tblM2016 also does a quotename call to make sure the @table_name, @table_schema, and @database_name passed to spM2016_CheckColumnExistence_tblM2016 has proper escaping as well. But, since I passed the already quotenamed @table_name, @table_schema, and @database_name from spM2016_ChangePKConstraints_tblM2016 into spM2016_CheckColumnExistence_tblM2016 as @col_names, @tbl_name, @db_name, @tbl_schema, they got double quoted and were thus unrecognizable when doing comparisons in the sys.object queries in spM2016_CheckColumnExistence_tblM2016 and so were returning bogus results.

The reason the test code worked is because the parameters were not already escaped when passed into the spM2016_CheckColumnExistence_tblM2016, thus causing the table variable to execute fine.

Turns out, it had nothing to do with the table variable :/

Answer 2

In your procedure, change the name of the table in your Declare section.

This should fix the issue.

ALTER PROCEDURE spM2016_ChangePKConstraints_tblM2016 
-- Add the parameters for the stored procedure here
    @constraint_names   nvarchar(max) = 
N'PK_tblM2016_Fields_M2016_Field_ID',
    @column_names       nvarchar(max) = N'M2016_Field_ID',
    @table_name         nvarchar(max) = N'tblM2016_Objects', 
    @table_schema       nvarchar(max) = N'dbo',
    @database_name      nvarchar(max) = N'MET',
    @debug              int = 0
AS
BEGIN
-- SET NOCOUNT ON added to prevent extra result sets from
-- interfering with SELECT statements.
SET NOCOUNT ON;

-- Insert statements for procedure here
DECLARE @tbl_name       nvarchar(max) = N'tblM2016_Objects',
        @col_names      nvarchar(max) = N'M2016_Field_ID',
        @tbl_schema     nvarchar(max) = N'dbo',
        @db_name        nvarchar(max) = N'MET',
        @tbl_full_name  nvarchar(max),
        @tbl_short_name nvarchar(max),
        @sql            nvarchar(max),
        @params         nvarchar(max)