Syntax error in compiling NLopt Fortran example code

Question

I'm exercising the NLopt example from http://ab-initio.mit.edu/wiki/index.php/NLopt_Tutorial using Simply Fortran (gfortran compiler). The NLopt library contains libnlopt-0.def, linlopt-0.dll (written in c), and nlopt.f. Here is my main program test.f

  program main
  external myfunc, myconstraint
  double precision lb(2)
  integer*8 opt
  double precision d1(2), d2(2)
  double precision x(2), minf
  integer ires
  include 'nlopt.f'

  opt=0
  call nlo_create(opt, NLOPT_LD_MMA, 2)
  call nlo_get_lower_bounds(ires, opt, lb)
  lb(2) = 0.0
  call nlo_set_lower_bounds(ires, opt, lb)
  call nlo_set_min_objective(ires, opt, myfunc, 0)

  d1(1) = 2.
  d1(2) = 0.
  call nlo_add_inequality_constraint(ires, opt, myconstraint, 
  $ d1, 1.D-8)
  d2(1) = -1.
  d2(2) = 1.
  call nlo_add_inequality_constraint(ires, opt, myconstraint, 
  $ d2, 1.D-8)

  call nlo_set_xtol_rel(ires, opt, 1.D-4)

  x(1) = 1.234
  x(2) = 5.678
  call nlo_optimize(ires, opt, x, minf)
  if (ires.lt.0) then
    write(*,*) 'nlopt failed!'
  else
    write(*,*) 'found min at ', x(1), x(2)
    write(*,*) 'min val = ', minf
  endif

  call nlo_destroy(opt)

  end 

  subroutine myfunc(val, n, x, grad, need_gradient, f_data)
  double precision val, x(n), grad(n)
  integer n, need_gradient
  if (need_gradient.ne.0) then
     grad(1) = 0.0
     grad(2) = 0.5 / dsqrt(x(2))
  endif
  val = dsqrt(x(2))
  end 

  subroutine myconstraint(val, n, x, grad, need_gradient, d)
  integer need_gradient
  double precision val, x(n), grad(n), d(2), a, b
  a = d(1)
  b = d(2)
  if (need_gradient.ne.0) then
    grad(1) = 3. * a * (a*x(1) + b)**2
    grad(2) = -1.0
  endif
  val = (a*x(1) + b)**3 - x(2)
  end          

It's written in Fortran 77, and it has 6 indents for each line. Building the file gives this error:

"C:\Program Files (x86)\Simply Fortran\mingw-w64\bin\gfortran.exe" -c -o     "build\test.o" -g -m32   -Jmodules ".\test.f"
 .\test.f:19.72:

  call nlo_add_inequality_constraint(ires, opt, myconstraint, d1, 1.
                                                                    1
   Error: Syntax error in argument list at (1)
   .\test.f:22.72:

  call nlo_add_inequality_constraint(ires, opt, myconstraint, d2, 1.
                                                                    1
  Error: Syntax error in argument list at (1)
  Error(E42): Last command making (build\test.o) returned a bad status
  Error(E02): Make execution terminated

However, call nlo_add_inequality_constraint has the right # of arguments, indicated by the NLopt reference:

  call nlo_add_inequality_constraint(ires, opt, fc, fc_data, tol)

Can anyone find out what's going on? Thanks a lot!

Answer 1

The error indicates a syntax error in your argument list, not a mismatch in the procedure call. The reason is that your line spans 2 source lines and your continuation character is not properly placed. You indicated your code is all indented 6 spaces, but the two continuation lines 20 and 23 must have the continuation character in column 6.

Edit the lines:

      call nlo_add_inequality_constraint(ires, opt, myconstraint, 
      $ d1, 1.D-8)
      d2(1) = -1.
      d2(2) = 1.
      call nlo_add_inequality_constraint(ires, opt, myconstraint, 
      $ d2, 1.D-8)

to:

      call nlo_add_inequality_constraint(ires, opt, myconstraint, 
     $ d1, 1.D-8)
      d2(1) = -1.
      d2(2) = 1.
      call nlo_add_inequality_constraint(ires, opt, myconstraint, 
     $ d2, 1.D-8)

The presence of any character except space or zero in column 6 indicates that the line is a continuation of the previous line (see 3.3.3.3 Fortran 2008).