TableLayoutPanel individual cell color

Question

I have 10 by 10 tablelayoutpanel and a 10 by 10 array in vb.net. I want to be able to click on a cell with a mouse and that particular cell would change color and the corresponding array element would be a 1. The cell not clicked would have a 0 in array and so on. Click another cell, the cell changes color and corresponding array element gets updated.

I am not sure how to change the color of individual cells in the tableLayoutPanel once the mouse button is clicked on that cell.

Tried looking for ideas by google searching but cannot seem to find something concrete. Any help would be much appreciated.

Answer 1

The cells aren't controls and don't provide individual control over back color. You could put a panel in each cell and add handlers at runtime. This example will toggle the color between red and blue of each cell you have in your TLP

Private panels As New Dictionary(Of Panel, Point)()
Private values(9, 9) As Integer

Private Sub PanelClick(sender As Object, e As EventArgs)
    Dim s = DirectCast(sender, Panel)
    Dim x = panels(s).X
    Dim y = panels(s).Y
    values(x, y) = If(values(x, y) = 0, 1, 0)
    s.BackColor = If(values(x, y) = 0, Color.Red, Color.Blue)
End Sub

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    For i = 0 To TableLayoutPanel1.ColumnCount - 1
        For j = 0 To TableLayoutPanel1.RowCount - 1
            Dim s = TableLayoutPanel1.GetControlFromPosition(i, j)
            If s IsNot Nothing Then
                Dim p = DirectCast(TableLayoutPanel1.GetControlFromPosition(i, j), Panel)
                panels.Add(p, New Point(i, j))
                AddHandler p.Click, AddressOf PanelClick
            End If
        Next
    Next
End Sub