TextFSM nxos template

Question

I have started exploring TextFSM by google, its great for screen scraping. But I'm stuck. Here is the template for the command: "show ip community-list"

Value TYPE (Standard|Extended)
Value CLNAME (\D+)
Value SEQ (\d+)
Value ACTION (permit|deny)
Value ASNUM (\d+)
Value TAGNUM (\d+)

Start
  ^${TYPE}\s+Community\s+List\s+${CLNAME}\s+ -> Community

Community
  ^\s+${SEQ}\s+${ACTION}\s+${ASNUM}\s+:\s+${TAGNUM}\s+ -> Record Start

Raw output looks like:

Expanded Community List ROUTES_CL1
1 permit "11111:10000"
Standard Community List ROUTES_CL2
    1 permit 11111:10000
    2 permit 22222:10000
    3 permit 33333:10000

somereason doesn't parse into key and values.

Answer 1

There are several things which need to be fixed:

• Extended (in your template) vs Expanded (in your output)
• CLNAME has digits in it which won't be matched by \D+
• \s+:\s+ requires spaces around the colon which the output doesn't have
• The Community List name needs to be remembered as there may be multiple action lines to which it applies. Use "Filldown".

Using this template:

Value Filldown TYPE (Standard|Extended|Expanded)
Value Filldown CLNAME (\w+)
Value SEQ (\d+)
Value ACTION (permit|deny)
Value ASNUM (\d+)
Value TAGNUM (\d+)

Start 
  ^${TYPE}\s+Community\s+List\s+${CLNAME} 
  ^\s*${SEQ}\s+${ACTION}\s+"?${ASNUM}:${TAGNUM}"? -> Next.Record

EOF

Will give the parsed output of:

[['Expanded', 'ROUTES_CL1', '1', 'permit', '11111', '10000'],
 ['Standard', 'ROUTES_CL2', '1', 'permit', '11111', '10000'],
 ['Standard', 'ROUTES_CL2', '2', 'permit', '22222', '10000'],
 ['Standard', 'ROUTES_CL2', '3', 'permit', '33333', '10000']]

A similar example with further explanation can be found on the textfsm wiki.