Validates two fields in Elm and Elm-Form

Question

I'm using Elm Form https://github.com/etaque/elm-form, but I can't figure out the validations of two fields, I want to validate the password and password confirmation fields match.

This is what I have so far:

validate : Validation String RegUser
validate =
    map6 RegUser
        (field "email" email)
        (field "password" (string |> andThen nonEmpty))
        (field "passwordConfirmation" (string |> andThen nonEmpty))
        (field "firstName" (string |> defaultValue ""))
        (field "lastName" (string |> defaultValue ""))
        (field "companyName" (string |> defaultValue ""))

The whole code: https://github.com/werner/madison-elm/blob/master/src/elm/Components/Register/Models.elm

Thanks for any help.

Answer 1

The solution was close to the one provided by Chad, based on https://github.com/etaque/elm-form/issues/75#issuecomment-269861043:

validate : Validation TranslationId RegUser
validate =
    map6 RegUser
        (field "email" email)
        (field "password" (string |> andThen nonEmpty))
        ((field "password" string) |> andThen validateConfirmation)
        (field "firstName" (string |> defaultValue ""))
        (field "lastName" (string |> defaultValue ""))
        (field "companyName" (string |> defaultValue ""))

validateConfirmation : String -> Validation TranslationId String
validateConfirmation password =
    field "passwordConfirmation"
        (string
            |> andThen
                (\confirmation ->
                    if password == confirmation then
                        succeed confirmation
                    else
                        fail (customError PasswordNotMatch)
                )
        )

Answer 2

Any time you see packages that expose andThen, succeed, and fail functions, that's a good indication that you can "peel apart" the value to inspect and bind its value with another function. In this case, we can use andThen twice to build up a validation function that peeks inside two named fields and checks that they match:

matchingFields : String -> String -> Validation String String
matchingFields masterField confirmField =
    field masterField string
        |> andThen (\masterVal -> field confirmField string
        |> andThen (\confirmVal ->
            if masterVal == confirmVal then
                succeed masterVal
            else
                fail (customError "Values do not match")))

You can then use it in your overall validation function like this:

validate : Validation String RegUser
validate =
    map6 RegUser
        (field "email" email)
        (matchingFields "password" "passwordConfirmation" |> andThen nonEmpty)
        (field "passwordConfirmation" (string |> andThen nonEmpty))
        ...