Batch File: Assign Variable to Each Sub Directory.

Question

I am currently writing a help desk batch script, and I am currently running into an issue. I would like our help desk guys to be able to be prompted to select a user profile, once they select the user profile the script will copy the profile folder to a specified directory.

What I am having trouble with is assigning unique variables to each c:\users subfolders, which are essentially the profile names. If I can assign them to variables then I can just create a prompt menu referencing the variable.Do I even have the right start here? Here is my code to convert it to variable. How can I do this for each subdirectory? Any help would be greatly appreciated.

@echo off
for /f "delims=|" %%f in ('dir /b c:\users\') do (set profvar=%%f%%) 

Thank you very much for your help. Can this be achieved more efficiently with wmic?

Answer 1

I think this will do what you're asking for.

The first loop uses variable VARCOUNT as counter and creates a variable named profvar# where the # is the value of VARCOUNT.

The second loop loops from 1 to the value of VARCOUNT and prints the value of each variable with the number in front of it.

The SET /P SELPROF=... line prompts the user to enter a number and the last line prints the selected profile name.

@ECHO OFF 
SETLOCAL ENABLEDELAYEDEXPANSION
SET VARCOUNT=0

FOR /F "delims=|" %%f in ('dir /b c:\users\') DO (
  SET /A VARCOUNT+=1
  SET profvar!VARCOUNT!=%%f)

ECHO --------------------------------------
FOR /L %%V IN (1,1,!VARCOUNT!) DO (
  ECHO     %%V - !profvar%%V!
)
ECHO --------------------------------------

SET /P SELPROF=Enter the number of the profile to copy: 

ECHO Selected profile = !profvar%SELPROF%!

Answer 2

Here is the final code. It will copy some critical system information along with prompt you to copy the profile to a designated directory.

echo off
echo Welcome: %username%
set /p usbpath= "Enter a copy path:  "
echo Usb drive letter set to:%usbpath%
pushd %usbpath%

@echo off
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a%%b)

set mydir="syscollect_%computername%_%mydate%_%mytime%"
set profpath="user profile"

mkdir %mydir%
mkdir %profpath%

cd %mydir%

net start > running-services.txt
sc query > service-query.txt
Tasklist /v > tasklist.txt
nbtstat -s > nbtstat.txt
at > scheduledActiveTasks.txt
schtasks > scheduledtasks.txt
cd %mydir%
mkdir eventlogs
copy c:\windows\system32\winevt\Logs\*.* eventlogs
ipconfig /all > ipconfig.txt
systeminfo > systeminfo.txt
cmd.exe /c set > systemenv.txt
regedit /e regbackup.txt
wmic /output:bootconfig.txt bootconfig
wmic /output:activeprocesses.txt process get name, workingsetsize
wmic /output:Disk.txt /namespace:\\root\cimv2 path Win32_ComputerSystem get CurrentTimeZone,     Description, Domain, TotalPhysicalMemory, Model, Name, UserName
wmic /output:ProgramList.txt product get name,version
cd %mydir%
mkdir profile


@ECHO OFF 
SETLOCAL ENABLEDELAYEDEXPANSION
SET VARCOUNT=0

FOR /F "delims=|" %%f in ('dir /b c:\users\') DO (
SET /A VARCOUNT+=1
SET profvar!VARCOUNT!=%%f)

ECHO --------------------------------------
FOR /L %%V IN (1,1,!VARCOUNT!) DO (
ECHO     %%V - !profvar%%V!
)
ECHO --------------------------------------

SET /P SELPROF=Enter the number of the profile to copy: 

xcopy /e /y  c:\users\!profvar%SELPROF%!\*.* %usbpath%\%mydir%\profile

popd