How to iterate a lists in Terraform

Question

I have a code

resource "oci_core_security_list" "db_security_list" {
  count          = var.deploy_database ? 1 : 0
  compartment_id = var.network_compartment_id
  vcn_id         = var.vcn_id
  freeform_tags  = { "Component" = "Database" }
  display_name   = "test-db-sl"
  ingress_security_rules {
    protocol = "6" # TCP
    source   = var.compute_subnet_cidr
    tcp_options {
      max = "1522"
      min = "1522"
    }
  }
}

Currently the compute_subnet_cidr is having a single subnet cidr block

how can I iterate the if the compute_subnet_cidr is a list.

compute_subnet_cidr  = ["10.10.10.0/24", "10.10.10.1/24", "10.10.10.2/24"]

How can I change the above code?

Answer 1

Yes, you can use dynamic blocks:

resource "oci_core_security_list" "db_security_list" {
  count          = var.deploy_database ? 1 : 0
  compartment_id = var.network_compartment_id
  vcn_id         = var.vcn_id
  freeform_tags  = { "Component" = "Database" }
  display_name   = "test-db-sl"

  dynamic "ingress_security_rules" {    
      for_each   = var.compute_subnet_cidr
      content {
        protocol = "6" # TCP
        source   = ingress_security_rules.value
        tcp_options {
          max = "1522"
          min = "1522"
        }
     }
   }  

}