How to model consecutive location in opl integer programs?

Question

Can someone model this MIP problem? I could not think of a way to model the constraint "all balls of the same color has to be in consecutive locations"

Problem description:

There are 10 locations: 1 to 10, loc 1 worth $1, loc 2 worth $2 ... loc 10 worth $10
There are 10 balls: b1 to b10
There are 3 colors: red, green, blue. red worth $3, green worth $2, blue worth $1

assign each ball to a color and a distinctive location so that:

all balls of the same color are next to each other in consecutive locations. for example, all red balls take location 4,5,6 is ok, but not 4,5,8
no color can be assigned to more than 4 balls
each color has to be assigned to at least 1 ball

ball in a location is worth $color * $loc, for example, red ball in loc 5 = $3 * $5 = $15

maximize total worth of the assignment 

Obviously the solution is: blue, blue, green, green, green, green, red, red, red, red

This is an illustrative problem to see how to model consecutive constraint in mip.

I have following opl program without even the neighboring constraint, it takes very long, for such a small problem, what did I do wrong?

range locations = 1..10;
int nbcolors=3;
int reward[l in locations]=l;
range colors=1..nbcolors;
string colorNames[colors]=["blue","green","red"];

dvar boolean assign[colors][locations];

dexpr int color[l in locations] = sum(c in colors) assign[c][l] * c;
dexpr int totalworth=sum(l in locations) color[l]*reward[l];
maximize totalworth;
subject to
{
  //each location assigned once
  forall(l in locations) sum(c in colors) assign[c][l] == 1;
  // no color can be assigned to more than 4 balls
  forall(c in colors) sum(l in locations) assign[c][l] <= 4;
  //each color has to be assigned to at least 1 ball
  forall(c in colors) sum(l in locations) assign[c][l] >= 1;
}

Thanks for your help.

Answer 1

I would write

using CP;
range locations = 1..10;
int nbcolors=3;
int reward[l in locations]=l;
range colors=1..nbcolors;
string colorNames[colors]=["blue","green","red"];

dvar int color[locations] in colors;

dexpr int totalworth=sum(l in locations) color[l]*reward[l];
maximize totalworth;
subject to
{
  // no color can be assigned to more than 4 balls
   //each color has to be assigned to at least 1 ball
  forall(c in colors) 1<=count(color,c)<=4;
  
  // consecutive locations
  sum(l in locations:l!=1) (color[l]!=color[l-1])==nbcolors-1;
}

string colorSolution[l in locations]=colorNames[color[l]];

execute
{
  writeln(colorSolution," ==> ",totalworth);
}

that gives

["blue" "blue" "green" "green" "green" "green" "red" "red" "red" "red"] ==> 141

that you can also rewrite as a MIP:

range locations = 1..10;
int nbcolors=3;
int reward[l in locations]=l;
range colors=1..nbcolors;
string colorNames[colors]=["blue","green","red"];

dvar int color[locations] in colors;
dvar boolean colorb[locations][colors];

dexpr int totalworth=sum(l in locations) color[l]*reward[l];
maximize totalworth;
subject to
{
  forall(l in locations) color[l]==sum(c in colors) c*colorb[l][c];
  forall(l in locations) sum(c in colors) colorb[l][c]==1;
  
  // no color can be assigned to more than 4 balls
   //each color has to be assigned to at least 1 ball
  forall(c in colors) 1<=sum(l in locations) colorb[l][c]<=4;
  
  // consecutive locations
  sum(l in locations:l!=1) (color[l]!=color[l-1])==nbcolors-1;
}

string colorSolution[l in locations]=colorNames[color[l]];

execute
{
  writeln(colorSolution," ==> ",totalworth);
}