Moving strings into register with a loop 8051 assembly

Question

This code below successfully moves a given string into a register, in this case, register 1; using r2 as a counter. However, r2 has to be hardcoded with the length of the string for the loop to finalize correctly. Is it possible to implement a similar solution without hardcoding a counter?

ORG     100H
            MOV     R2, #13D
                MOV R1, #0
                MOV     DPTR,#DAT0
    AGAIN:      MOV     A, R1
            MOVC    A, @ A+DPTR
            MOV P1, A
            INC     R1
            DJNZ    R2, AGAIN
            SJMP    $
DAT0:       DB  "(C) XYZ Inc.",0
    END

Answer 1

If you don't want to send the terminating zero byte to P1, then jump out of the loop with the JZ instruction that jumps if the accumulator A contains zero:

  ORG     100h
  MOV     R2, #0       ; Offset in string
  MOV     DPTR, #DAT0  ; Start of string
More:
  MOV     A, R2
  MOVC    A, @A+DPTR   ; Get character of the string
  JZ      Done         ; JUMPS IF A==0
  MOV     P1, A        ; Send A to P1 (excluding 0)
  INC     R2
  SJMP    More
Done:
  SJMP    $
DAT0:     DB  "(C) XYZ Inc.",0
  END

If you do want to send the terminating zero byte to P1, then only loop back if the last byte send was non-zero. Use the JNZ instruction that jumps if the accumulator A contains anything but zero:

  ORG     100h
  MOV     R2, #0       ; Offset in string
  MOV     DPTR, #DAT0  ; Start of string
More:
  MOV     A, R2
  MOVC    A, @A+DPTR   ; Get character of the string
  MOV     P1, A        ; Send A to P1 (including 0)
  INC     R2
  JNZ     More         ; DOESN'T JUMP IF A==0
  SJMP    $
DAT0:     DB  "(C) XYZ Inc.",0
  END