To make output LED blink in moore machine

Question

What I'm designing is a moore machine that gives particular color for each state. Here's a part of my code.

    always @(*) begin            
        case (state)
            S0 : led = 6'b111111;
            S1 : led = 6'b010100;  // have to blink //
            S2 : led = 6'b100010;
            S3 : led = 6'b110110; 
            default : led_output = 6'b000000;
        endcase
    end
    

endmodule

Before the code shown above, there are codes about assigning state corresponding to the input.

The code shown above is to determine the output value of moore machine. (Therefore the condition is *)

What I left is to assign led output value for each state.

However the condition for S1 is not only particular color but it has to 'blink' for period of 1s.

I already googled for 'blink LED' verilog code but they were little bit different from my situation.

I have no idea of coding block that is needed.

Can you give me some advice or answer for what to add to make S1 to blink?

Answer 1

To make it blink, you need to distinguish 2 states. So create a 1-bit signal, say sel, which toggles in S1 state, and its toggle speed as well as its duty meet your requirement in 'blink' for period of 1s. This is basically implemented with the help of a counter.

reg [3:0] cnt; // assume 4-bit long
reg sel;

// counter to determine the HIGH / LOW time of sel.
always@(posedge clk or negedge resetn)begin
    if(!resetn)begin
        cnt <= 4'h0;
    end
    // since you can exit S1 state at any time using push_button,
    // make sure cnt is always ZERO when entering S1 state next time.
    // also to save power when using clock gating, because this statement
    // is only active for 1 cycle.
    else if((state == S1) & ((push_button == 2'b01) | (push_button == 2'b10)))begin  // S1 exit condition
        cnt <= 4'h0;
    end
    else if(state == S1)begin
        // sel HIGH lasts <HIGH_MAX_VAL>+1 cycles
        // sel LOW lasts <LOW_MAX_VAL>+1 cycles
        if(cnt == (sel ? <HIGH_MAX_VAL> : <LOW_MAX_VAL>))begin
            cnt <= 4'h0;
        end
        else begin
            cnt <= cnt + 4'h1;
        end
    end
end

always@(posedge clk or negedge resetn)begin
    if(!resetn)begin
        sel <= 1'h0;
    end
    else if((state == S1) & ((push_button == 2'b01) | (push_button == 2'b10)))begin
        sel <= 1'h0;
    end
    else if(state == S1)begin
        if(cnt == (sel ? <HIGH_MAX_VAL> : <LOW_MAX_VAL>))begin
            sel <= ~sel;
        end
    end
end

Use sel to select between 2 led values.

always@(*)begin            
    case(state)
        ....
        S1 : led = sel ? 6'b010100 : <ANOTHER_VALUE>;
        ....
    endcase
end