XQuery != operator with a sequence

Question

I am running into the following problem, and syntax wise I am not sure why I am getting the results that I am getting.

I have the following FLOWR expression:

(: example 1 :)
for $attr in $node/@*
where $attr/fn:local-name != ("src", "type", "id")
return $attr

The English version of this is in my mind is: Get me all the attributes that are not src, type, or id.

However, when I run this, every attribute gets returned, including src, type, and id. When I change my where statement to just have one element, where $attr/fn:local-name != ("src"), then this works as expected - all the attributes except for src gets returned. Weird, it works when comparing to one element, but not to three.

If I reverse my logic, and make a statement like this:

(: example 2 :)
for $attr in $node/@*
where $attr/fn:local-name = ("src", "type", "id")
return $attr
(: difference is = instead of != :)

then I also I get the results I expect, which are just the 3 attributes "src", "type", and "id", and nothing else.

So, back to my original case, in order to get it to work the way that I am expecting, I must use the following statement:

(: example 3 :)
for $attr in $node/@*
where fn:not($attr/fn:local-name = ("src", "type", "id"))
return $attr

And this returns all the attributes except for src, type, and id.

Why is this happening the way that it is happening? In my mind, example 1 and example 3 should do the same thing. However, I cannot get example 1 to work the way that I am expecting it to.

The xPath equivalent of my question looks similar to:

$node/@*[fn:not(./fn:local-name(.) = ("src", "type", "id"))]

Can anybody explain where my thinking is faulty?

I am using xquery version "1.0-ml".

Answer 1

The problem is when you think that you reverse the logic by changing != into =. But the are not the opposite of each other.

= is true when any item in the left-hand side sequence is equal to any item in the right-hand side sequence. != is true when any item in the left-hand side sequence is different from any item in the right-hand side sequence.

( 1, 2, 3 ) = ( 1, 5 )  (: true :)
( 1, 2, 3 ) = ( )       (: false :)
( 1, 2, 3 ) != ( 1, 5 ) (: true :)

The opposite of x=y, as you found out, is not(x=y).

When the left-hand side sequence or the right-hand side sequence is a singleton, then by definition not(x=y) equals x!=y.

Answer 2

When you say $x != (1, 2, 3) that translates to $x does not equal 1, 2, and 3. The != operator will return true if any of the values on the left and right hand sides are not equal, so if $x is 1, this still returns true because $x doesn't equal 2 or 3.